巧用批次處理指令移除空資料夾

[psac]

巧用批次處理指令移除空資料夾

有人問我，什麼工具能尋找和移除硬碟上所有空的資料夾，或只包含空的子資料夾的資料夾?殺雞焉用宰牛刀，其實不用任何軟體，直接使用批次處理指令就能實現這個目的。

　　第一步:進入Windows的MS-DOS視窗(Windows 2000/XP叫指令行提示號)，進入要搜尋空資料夾的驅動器，執行:

　　dir /ad/b/s | sort /r >empties.bat。

　　小提示

　　上面指令行中「|」的輸入方法是按住Shift鍵按「\」鍵。

　　第二步:指令執行後，當前目錄下會產生一個Empties.bat文件，其中包含了逆序排列的所有資料夾的清單。用Word或記事本開啟該檔案，把每一行內容分別放入一對英文引號之內，然後在每一行前面插入「rd 」前綴(rd後加一個空格)。

　　以Word為例，按Ctrl+H開啟「搜尋和取代」功能，搜尋「^p」(不含引號，下同。「^p」可以使用以下方法輸入:在「搜尋和取代」對話視窗中點「進階」按鈕，然後點擊「特殊字元→段落標記」)，取代成「^prd 」(rd後面加一個空格)，然後手動式修正第一行和最後一行的內容。儲存修改後的Empties.bat文件，進入指令行視窗執行這個批次處理文件。Empties.bat將試圖移除(即rd指令的作用)每一個資料夾，但包含內容的資料夾不可能用rd指令移除，結果就移除了所有空的資料夾。

　　知其所以然:我們來瞭解一下前面Dir指令的執行原理:「/ad」要求Dir指令選出所有目錄;「/b」表示只顯示資料夾名稱(不顯示Dir指令的標題訊息或摘要);「/s」表示搜尋，即搜尋當前資料夾及其所有的子資料夾。Dir指令的輸出通過管道指令(「|」)傳送給Sort指令。Sort指令的作用是排序，「/r」選項表示逆序排列。

　　最後，Sort指令的輸出被重轉發IP(「>」)到Empties.bat文件。由於要求Sort指令逆序排列輸出結果，所以Empties.bat文件中子資料夾總是位於父資料夾的前面，因而移除資料夾時，空的子資料夾總是先被移除，空的父資料夾也得以被移除。可以看到，巧妙運用Windows內建指令，許多表面上看起來複雜的工作也可以輕而易舉地完成!

　　小提示：Dir的三個小招數

　　★檢視資料夾全部隱藏文件:如果想檢視Windows資料夾和它所有子資料夾中全部的隱藏文件，只需輸入IR C:\Windows.* /AH/S/B/P。

　　★輕鬆新增長檔案名文件列表:你可以新增一個批次處理文件如Getlist.bat，其中的內容只有DIR *.* /B >LIST.TXT，將它複製到要新增文件列表的資料夾，然後雙按執行即可將資料夾所有文件的列表儲存到List.txt文件中。

　　★多個目錄齊現身:如果想同時列出C碟和D碟根目錄下的內容，那麼只要輸入IR C: D:即可。

[psac]

批次處理教學

延伸名是bat(在nt/2000/xp/2003下也可以是cmd)的文件就是批處理文件。

首先批處理文件是一個文本文件，這個文件的每一行都是一條DOS命令（大部分時候就好像我們在DOS提示字元下執行的命令行一樣），你可以使用DOS下的Edit或者Windows的記事本(notepad)等任何文本文件編輯工具創建和修改批處理文件。

其次，批處理文件是一種簡單的程式，可以通過條件語句(if)和流程控制語句(goto)來控制命令執行的流程，在批處理中也可以使用循環語句(for)來循環執行一條命令。當然，批處理文件的編程能力與C語言等編程語句比起來是十分有限的，也是十分不規範的。批處理的程式語句就是一條條的DOS命令（包括內部命令和外部命令），而批處理的能力主要取決於你所使用的命令。

第三，每個編寫好的批處理文件都相當於一個DOS的外部命令，你可以把它所在的目錄放到你的DOS搜索路徑(path)中來使得它可以在任意位置執行。一個良好的習慣是在硬碟上建立一個bat或者batch目錄（例如C:\BATCH），然後將所有你編寫的批處理文件放到該目錄中，這樣只要在path中設置上c:\batch，你就可以在任意位置執行所有你編寫的批處理程式。

第四，在DOS和Win9x/Me系統下，C:盤根目錄下的AUTOEXEC.BAT批處理文件是自動執行批處理文件，每次系統啟動時會自動執行該文件，你可以將系統每次啟動時都要執行的命令放入該文件中，例如設置搜索路徑，調入滑鼠驅動和磁碟快取記憶體，設置系統環境變數等。下面是一個執行於Windows 98下的autoexec.bat的示例：
@ECHO OFF
PATH C:\WINDOWS;C:\WINDOWS\COMMAND;C:\UCDOS;C:\DOSTools;C:\SYSTOOLS;C:\WINTOOLS;C:\BATCH
LH SMARTDRV.EXE /X
LH DOSKEY.COM /INSERT
LH CTMOUSE.EXE
SET TEMP=D:\TEMP
SET TMP=D:\TEMP


批處理的作用
簡單的說，批處理的作用就是自動的連續執行多條命令。

這裡先講一個最簡單的應用：在啟動wps軟件時，每次都必須執行（>前面內容表示DOS提示字元）：
C:\>cd wps
C:\WPS>spdos
C:\WPS>py
C:\WPS>wbx
C:\WPS>wps
如果每次用WPS之前都這樣執行一遍，您是不是覺得很麻煩呢？

好了，用批處理，就可以實現將這些麻煩的操作簡單化，首先我們編寫一個runwps.bat批處理文件，內容如下：
@echo off
c:
cd\wps
spdos
py
wbx
wps
cd\

以後，我們每次進入wps，只需要執行runwps這個批處理文件即可。

常用命令

echo、@、call、pause、rem(小技巧：用::代替rem)是批處理文件最常用的幾個命令，我們就從他們開始學起。
echo 表示顯示此命令後的字元
echo off 表示在此語句後所有執行的命令都不顯示命令行本身
@與echo off相像，但它是加在每個命令行的最前面，表示執行時不顯示這一行的命令行（只能影響當前行）。
call 呼叫另一個批處理文件（如果不用call而直接呼叫別的批處理文件，那麼執行完那個批處理文件後將無法返回當前文件並執行當前文件的後續命令）。
pause 執行此句會暫停批處理的執行並在螢幕上顯示Press any key to continue...的提示，等待用戶按任意鍵後繼續
rem 表示此命令後的字元為解釋行（註釋），不執行，只是給自己今後參考用的（相當於程式中的註釋）。

例1：用edit編輯a.bat文件，輸入下列內容後存盤為c:\a.bat，執行該批處理文件後可實現：將根目錄中所有文件寫入 a.txt中，啟動UCDOS，進入WPS等功能。

　　批處理文件的內容為: 　　　　　　　 命令註釋：

　　　　@echo off　　　　　　　　　　　不顯示後續命令行及當前命令行
　　　　dir c:\*.* >a.txt　　　　　　　將c盤文件列表寫入a.txt
　　　　call c:\ucdos\ucdos.bat　　　　呼叫ucdos
　　　　echo 你好 　　　　　　　　　　 顯示"你好"
　　　　pause 　　　　　　　　　　　　 暫停,等待按鍵繼續
　　　　rem 準備執行wps 　　　　　　　 註釋：準備執行wps
　　　　cd ucdos　　　　　　　　　　　 進入ucdos目錄
　　　　wps 　　　　　　　　　　　　　 執行wps　　

批處理文件的參數

批處理文件還可以像C語言的函數一樣使用參數（相當於DOS命令的命令行參數），這需要用到一個參數表示符「%」。

%[1-9]表示參數，參數是指在執行批處理文件時在文件名後加的以空格（或者Tab）分隔的字元串。變數可以從%0到%9，%0表示批處理命令本身，其它參數位符串用%1到%9順序表示。

例2：C:根目錄下有一批處理文件名為f.bat，內容為：
@echo off
format %1

如果執行C:\>f a:
那麼在執行f.bat時，%1就表示a:，這樣format %1就相當於format a:，於是上面的命令執行時實際執行的是format a:

例3：C:根目錄下一批處理文件名為t.bat，內容為:
@echo off
type %1
type %2

那麼執行C:\>t a.txt b.txt
%1 : 表示a.txt
%2 : 表示b.txt
於是上面的命令將順序地顯示a.txt和b.txt文件的內容。


特殊命令

if goto choice for是批處理文件中比較高階的命令，如果這幾個你用得很熟練，你就是批處理文件的專家啦。

一、if 是條件語句，用來判斷是否符合規定的條件，從而決定執行不同的命令。 有三種格式:

1、if [not] "參數" == "字元串" 待執行的命令

參數如果等於(not表示不等，下同)指定的字元串，則條件成立，執行命令，否則執行下一句。

例：if "%1"=="a" format a:

2、if [not] exist [路徑\]文件名 待執行的命令
如果有指定的文件，則條件成立，執行命令，否則執行下一句。

如: if exist c:\config.sys type c:\config.sys
表示如果存在c:\config.sys文件，則顯示它的內容。

3、if errorlevel <數位> 待執行的命令

很多DOS程式在執行結束後會返回一個數位值用來表示程式執行的結果(或者狀態)，通過if errorlevel命令可以判斷程式的返回值，根據不同的返回值來決定執行不同的命令(返回值必須按照從大到小的順序排列)。如果返回值等於指定的數位，則條件成立，執行命令，否則執行下一句。

如if errorlevel 2 goto x2

二、goto 批處理文件執行到這裡將跳到goto所指定的標號(標號即label，標號用:後跟標準字元串來定義)處，goto語句一般與if配合使用，根據不同的條件來執行不同的命令組。

如:

goto end

:end
echo this is the end

標號用「:字元串」來定義，標號所在行不被執行。

三、choice 使用此命令可以讓用戶輸入一個字元（用於選擇），從而根據用戶的選擇返回不同的errorlevel，然後於if errorlevel配合，根據用戶的選擇執行不同的命令。

注意：choice命令為DOS或者Windows系統提供的外部命令，不同版本的choice命令語法會稍有不同，請用choice /?檢視用法。

choice的命令語法（該語法為Windows 2003中choice命令的語法，其它版本的choice的命令語法與此大同小異）：

CHOICE [/C choices] [/N] [/CS] [/T timeout /D choice] [/M text]

描述:
該工具允許用戶從選擇列表選擇一個專案並返回所選專案的索引。

參數列表:
/C choices 指定要創建的選項列表。預定列表是 "YN"。

/N 在提示字元中隱藏選項列表。提示前面的消息得到顯示，
選項依舊處於啟用狀態。

/CS 允許選擇分大小寫的選項。在預定情況下，這個工具
是不分大小寫的。

/T timeout 做出預定選擇之前，暫停的秒數。可接受的值是從 0
到 9999。如果指定了 0，就不會有暫停，預定選項
會得到選擇。

/D choice 在 nnnn 秒之後指定預定選項。字元必須在用 /C 選
項指定的一組選擇中; 同時，必須用 /T 指定 nnnn。

/M text 指定提示之前要顯示的消息。如果沒有指定，工具只
顯示提示。

/? 顯示幫助消息。

注意:
ERRORLEVEL 環境變數被設置為從選擇集選擇的鍵索引。列出的第一個選
擇返回 1，第二個選擇返回 2，等等。如果用戶按的鍵不是有效的選擇，
該工具會發出警告響聲。如果該工具檢測到錯誤狀態，它會返回 255 的
ERRORLEVEL 值。如果用戶按 Ctrl+Break 或 Ctrl+C 鍵，該工具會返回 0
的 ERRORLEVEL 值。在一個批程式中使用 ERRORLEVEL 參數時，將參數降
序排列。

示例:
CHOICE /?
CHOICE /C YNC /M "確認請按 Y，否請按 N，或者取消請按 C。"
CHOICE /T 10 /C ync /CS /D y
CHOICE /C ab /M "選項 1 請選擇 a，選項 2 請選擇 b。"
CHOICE /C ab /N /M "選項 1 請選擇 a，選項 2 請選擇 b。"

如果我執行命令：CHOICE /C YNC /M "確認請按 Y，否請按 N，或者取消請按 C。"
螢幕上會顯示：
確認請按 Y，否請按 N，或者取消請按 C。 [Y,N,C]?


例：test.bat的內容如下（注意，用if errorlevel判斷返回值時，要按返回值從高到低排列）:
@echo off
choice /C dme /M "defrag,mem,end"
if errorlevel 3 goto end
if errorlevel 2 goto mem
if errotlevel 1 goto defrag

:defrag
c:\dos\defrag
goto end

:mem
mem
goto end

:end
echo good bye

此批處理執行後，將顯示「defrag,mem,end[D,M,E]?」 ，用戶可選擇d m e ，然後if語句根據用戶的選擇作出判斷，d表示執行標號為defrag的程式段，m表示執行標號為mem的程式段，e表示執行標號為end的程式段，每個程式段最後都以goto end將程式跳到end標號處，然後程式將顯示good bye，批處理執行結束。

四、for 循環命令，只要條件符合，它將多次執行同一命令。

語法：
對一組文件中的每一個文件執行某個特定命令。

FOR %%variable IN (set) DO command [command-parameters]

%%variable 指定一個單一字母可替換的參數。
(set) 指定一個或一組文件。可以使用通配符。
command 指定對每個文件執行的命令。
command-parameters
為特定命令指定參數或命令行開關。

例如一個批處理文件中有一行:
for %%c in (*.bat *.txt) do type %%c

則該命令行會顯示當前目錄下所有以bat和txt為延伸名的文件的內容。


批處理示例

1. IF-EXIST

1)

首先用記事本在C:\建立一個test1.bat批處理文件，文件內容如下：
@echo off
IF EXIST \AUTOEXEC.BAT TYPE \AUTOEXEC.BAT
IF NOT EXIST \AUTOEXEC.BAT ECHO \AUTOEXEC.BAT does not exist

然後執行它：
C:\>TEST1.BAT

如果C:\存在AUTOEXEC.BAT文件，那麼它的內容就會被顯示出來，如果不存在，批處理就會提示你該文件不存在。

2)

接著再建立一個test2.bat文件，內容如下：
@ECHO OFF
IF EXIST \%1 TYPE \%1
IF NOT EXIST \%1 ECHO \%1 does not exist

執行:
C:\>TEST2 AUTOEXEC.BAT
該命令執行結果同上。

說明：
(1) IF EXIST 是用來測試文件是否存在的，格式為
IF EXIST [路徑+文件名] 命令
(2) test2.bat文件中的%1是參數，DOS允許傳遞9個批參數訊息給批處理文件，分別為%1~%9(%0表示test2命令本身) ，這有點像編程中的實參和形參的關係，%1是形參，AUTOEXEC.BAT是實參。

3) 更進一步的，建立一個名為TEST3.BAT的文件，內容如下：
@echo off
IF "%1" == "A" ECHO XIAO
IF "%2" == "B" ECHO TIAN
IF "%3" == "C" ECHO XIN

如果執行：
C:\>TEST3 A B C
螢幕上會顯示:
XIAO
TIAN
XIN

如果執行：
C:\>TEST3 A B
螢幕上會顯示
XIAO
TIAN

在這個命令執行過程中，DOS會將一個空字元串指定給參數%3。

2、IF-ERRORLEVEL

建立TEST4.BAT，內容如下：
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:IF ERRORLEVEL 1 ECHO 文件拷貝失敗
IF ERRORLEVEL 0 ECHO 成功拷貝文件

然後執行文件:
C:\>TEST4

如果文件拷貝成功，螢幕就會顯示「成功拷貝文件」，否則就會顯示「文件拷貝失敗」。

IF ERRORLEVEL 是用來測試它的上一個DOS命令的返回值的，注意只是上一個命令的返回值，而且返回值必須依照從大到小次序順序判斷。
因此下面的批處理文件是錯誤的：
@ECHO OFF
XCOPY C:\AUTOEXEC.BAT D:\
IF ERRORLEVEL 0 ECHO 成功拷貝文件
IF ERRORLEVEL 1 ECHO 未找到拷貝文件
IF ERRORLEVEL 2 ECHO 用戶通過ctrl-c中止拷貝操作
IF ERRORLEVEL 3 ECHO 預置錯誤阻止文件拷貝操作
IF ERRORLEVEL 4 ECHO 拷貝過程中寫盤錯誤

無論拷貝是否成功，後面的：

未找到拷貝文件
用戶通過ctrl-c中止拷貝操作
預置錯誤阻止文件拷貝操作
拷貝過程中寫盤錯誤

都將顯示出來。

以下就是幾個常用命令的返回值及其代表的意義：
backup
0 備份成功
1 未找到備份文件
2 文件共享衝突阻止備份完成
3 用戶用ctrl-c中止備份
4 由於致命的錯誤使備份操作中止

diskcomp
0 盤比較相同
1 盤比較不同
2 用戶通過ctrl-c中止比較操作
3 由於致命的錯誤使比較操作中止
4 預置錯誤中止比較

diskcopy
0 盤拷貝操作成功
1 非致命盤讀/寫錯
2 用戶通過ctrl-c結束拷貝操作
3 因致命的處理錯誤使盤拷貝中止
4 預置錯誤阻止拷貝操作

format
0 格式化成功
3 用戶通過ctrl-c中止格式化處理
4 因致命的處理錯誤使格式化中止
5 在提示「proceed with format（y/n）?」下用戶鍵入n結束

xcopy
0 成功拷貝文件
1 未找到拷貝文件
2 用戶通過ctrl-c中止拷貝操作
4 預置錯誤阻止文件拷貝操作
5 拷貝過程中寫盤錯誤

3、IF STRING1 == STRING2

建立TEST5.BAT，文件內容如下：
@echo off
IF "%1" == "A" FORMAT A:

執行：
C:\>TEST5 A
螢幕上就出現是否將A:盤格式化的內容。

注意：為了防止參數為空的情況，一般會將字元串用雙引號（或者其它符號，注意不能使用保留符號）括起來。
如：if [%1]==[A] 或者 if %1*==A*

5、GOTO

建立TEST6.BAT，文件內容如下：
@ECHO OFF
IF EXIST C:\AUTOEXEC.BAT GOTO _COPY
GOTO _DONE
:_COPY
COPY C:\AUTOEXEC.BAT D:\
:_DONE

注意：
(1) 標號前是ASCII字元的冒號":"，冒號與標號之間不能有空格。
(2) 標號的命名規則與文件名的命名規則相同。
(3) DOS支持最長八位字元的標號，當無法區別兩個標號時，將跳轉至最近的一個標號。

6、FOR

建立C:\TEST7.BAT，文件內容如下：
@ECHO OFF
FOR %%C IN (*.BAT *.TXT *.SYS) DO TYPE %%C

執行：
C:>TEST7

執行以後，螢幕上會將C:盤根目錄下所有以BAT、TXT、SYS為延伸名的文件內容顯示出來（不包括隱藏文件）