疑問 - VB6.0載入圖片解析度限制

[mini]

作者: chung1206

版大您好，如果我只要存成bmp檔就好dpi300這樣會不會比較簡單點？JPG的部份蠻複雜的，我真得看不太懂，謝謝。

根據 http://www.atlaspost.com/landmark-339129.htm 上的 Bitmap File Header
其水平與垂直解析度記載於
0026h H-Resolution 4 水平解析度（單位：像素/公尺）【註８】
002Ah V-Resolution 4 垂直解析度（單位：像素/公尺）
...

【註８】若要換算為 dpi，則將此欄數值要除以39.37（吋/公尺）
　　　　例如，此欄數值若為 2834 (pixels per meter), 
　　　　則 2834 ÷ 39.37 = 72 (pixels per inch) = 72 dpi

所以改成

            '**圖像改解析度**
            Dim byteData(&h2B) As Byte

            Open .FileName For Binary Access Read As #1
            Get #1, , byteData()
            Close #1
    
            '將影像解析度改成 150 dpi = 150*39.37 =取整數=> 5906 = 十六進制 17 12
            byteData(&H26) = &H12
            byteData(&H27) = &H17
            byteData(&H2A) = &H12
            byteData(&H2B) = &H17

            Open .FileName For Binary Access Write As #1
            Put #1, , byteData()
            Close #1
            '**************

300 dpi的話是 300*39.37=11811=2E 23

因為電腦讀檔案是以堆疊方式讀出
所以寫入時也就是用倒序方式寫入讀檔
所以要倒過來先填入 &H23 再填 &H2E
byteData(&H26) = &H23
byteData(&H27) = &H2E

[chung1206]

感謝版大，我發現我錯了，我發現它一載入圖片時解析度就變成72，而不是存檔後才改變的，這樣我是不是要在開啟圖檔那就要改了？謝謝。

[mini]

作者: chung1206

感謝版大，我發現我錯了，我發現它一載入圖片時解析度就變成72，而不是存檔後才改變的，這樣我是不是要在開啟圖檔那就要改了？謝謝。

都可以.....

[chung1206]

作者: mini

都可以.....

SORRY版大，我還是一直有出現錯誤訊息，我可以傳我整個原始專案請您幫我看一下嗎？
謝謝。

[mini]

那要處理的圖檔也不須附上...

[mini]

作者: chung1206

SORRY版大，我還是一直有出現錯誤訊息，我可以傳我整個原始專案請您幫我看一下嗎？
謝謝。

看了一下 請問哪裡出錯 ...

[chung1206]

作者: mini

看了一下 請問哪裡出錯 ...

這是還未加進版大的程式前的，所以沒有錯誤訊息，但加入您調整DPI的程式後就會出現，謝謝。

PS:按另存圖檔後會出現不正確的引用，在這行Open .FileName For Binary Access Read As #1

[mini]

加了個 ChangeFileDPI 副程式
及改良 Command2_Click()

不過你那個存檔方式還是只能存成 BMP格式 (只是改個副檔名成 .jpg實際上是掩耳盜鈴 ...)

Private Sub Command2_Click()
Dim i As Integer
    
    For i = Image1.LBound To Image1.UBound
        Image1(i).Picture = LoadPicture()
    Next
    Picture1.Refresh
    
End Sub

Private Sub Command3_Click()
Dim i As Integer, X As Long, Y As Long
    
    Picture1.AutoRedraw = True
    Picture1.Width = Image1(0).Width * 4
    Picture1.Height = Image1(0).Height * 2
    X = 0: Y = 0
    
    For i = 0 To 7
        If Image1(i).Picture <> 0 Then
            Picture1.PaintPicture Image1(i).Picture, X, Y, Image1(i).Width, Image1(i).Height
        End If
        X = X + Image1(0).Width
        If i = 3 Then
            X = 0
            Y = Y + Image1(0).Height
        End If
    Next
   
    With CommonDialog2
        .FileName = ""
        .Filter = "JPEG files (*.jpg) |*.jpg|BMP files (*.bmp) |*.bmp"
        .ShowSave
        If .FileName = "" Then Exit Sub
        
        SavePicture Picture1.Image, .FileName '存檔成 BMP
        ChangeFileDPI .FileName '改成適當DPI
    End With

End Sub

'改成適當DPI
Private Sub ChangeFileDPI(sFileName As String, Optional iDPI = 300#)  '預設 DPI為 300
Dim lFileID As Long
Dim byteData() As Byte
Dim sDPI As String, sMode As String
Dim bHiByte As Byte, bLoByte As Byte

    sMode = LCase(Right(sFileName, 3)) '得到最右邊的副檔名並統一轉成小寫
    If sMode = "bmp" Then iDPI = iDPI * 39.37 '如果是 BMP檔需換算
    
    sDPI = Right("0000" & Hex(iDPI), 4)     '將數字轉成四位形式的十六進位字串
    bHiByte = CByte("&H" & Left(sDPI, 2))   '取左邊兩個
    bLoByte = CByte("&H" & Right(sDPI, 2))  '取右邊兩個

    lFileID = FreeFile '向系統取得一個尚未被使用的檔案代碼
    
    '**改變 JPEG圖檔 解析度**
    If sMode = "jpg" Then
        ReDim byteData(17) As Byte
        
        '*取出適當的File Header資訊
        Open sFileName For Binary Access Read As #lFileID
        Get #lFileID, , byteData()
        Close #lFileID
        
        '換上所需的 DPI資訊
        byteData(14) = bHiByte
        byteData(15) = bLoByte
        byteData(16) = bHiByte
        byteData(17) = bLoByte

    '**改變 BMP圖檔 解析度**
    ElseIf sMode = "bmp" Then
        ReDim byteData(&H2B) As Byte
        
        Open sFileName For Binary Access Read As #lFileID
        Get #lFileID, , byteData()
        Close #lFileID
    
        byteData(&H26) = bLoByte
        byteData(&H27) = bHiByte
        byteData(&H2A) = bLoByte
        byteData(&H2B) = bHiByte

    Else
        Exit Sub
    End If
        
    '*存回
    Open sFileName For Binary Access Write As #lFileID
    Put #lFileID, , byteData()
    Close #lFileID
            
End Sub

其實 DPI應該根據 像素來算出適當的值
而不是固定用 300等固定值