分享 - UltraEdit 對中文化常使用的巨集心得與範例

[simonni]

軟體:UltraEdit 英文版(中文版)
作業環境:Windows XP SP2

說明:
在對軟體中文化時,使用字典檔翻譯並匯出來修改,修改時常常會發生不該出現的快
速鍵字元或是"..."等符號字元,往往要1個1個去修改又花時間,若是眼花沒修改到又
要再來一次。那要用什麼方式來做篩檢呢？用VB程式來做嗎？那要會寫VB...這麻煩
要花時間學,有簡單一點的嗎？答案：有 用巨集來篩檢

Excel 有巨集嗎？答案：有 但是要有 VB 底子,Excel 使用 VBA 作為內部使用巨集
文字編輯器有巨集嗎？答案：有 那應該比較簡單吧？哈哈....沒錯

以下為本人使用 UltraEdit 巨集的心得 及 範例

作法:
本人使用中文化的軟體是 SDL Passolo 2007 匯出翻譯字串為.csv使用Excel開啟後
將整個欄位的字串複製到 UltraEdit 使用巨集處理,處理完畢字串在複製回來Excel
存檔後在匯入SDL Passolo 2007

流程:
取得中文乾淨字串 如：編輯(&E)\tAlt+E 除了中文其他符號字元刪除因為來源功能
鍵可能不是(&E)/tAlt+E 如要一一比對太花時間。

取得來源英文字串 如：E&dit\tAlt+D &d 跟 \tAlt+D 的符號字元跟中文字串結合
這才是我要的正確翻譯字串。

1.字典用刪除多餘內容空格：清除中文字字串多的符號內容
2.留下功能鍵內容+括號：取得來源英文字串中的$符號+字元 如 $Edit 中的 &E 並加入括號
3.留下冒號3點：取得來源英文字串中的":"及"..."符號 如 File Name: 中的":"
4.留下\t內容：取得來源英文字串中的 \tAlt+F 如 &File\tAlt+F 中的"\tAlt+F"
5.留下大中小括弧內容：這個巨集是多寫的可以不用 功能:取得括號之間的內容 如：編輯(&E) 中的(&E)
建議使用 Ctrl+Alt+字元 作為巨集快速鍵,單獨 Ctrl+字元 或 Alt+字元 會跟
UltraEdit 相衝

上面 2. 3. 4. 必須每做完一項要在複製來源英文字串一次到 UltraEdit 處理,並
複製回 Excel 分別放到與中文字串鄰近不同欄位
如:A B C D E
123 &Edit\tAlt+E 編輯 (&E) \tAlt+E


Excel 字串與字串是用 TAB 做分隔,所以標記 C D E 欄位複製到文字編輯器刪除
TAB 複製回 Excel 就會變成同一個欄位
如:A B C
123 &Edit\tAlt+E 編輯(&E)\tAlt+E

那為何 2. 3. 4. 功能不作成1個,原因是 UltraEdit 巨集指令功能很陽春,無法像
VB 等之類的軟體有字串處理的能力,所以分開來處理。

ps:SDL Passolo 2007 匯出有提供功能鍵"&"字元匯出,但是"超級不準"不知是否我
有設定上錯誤
另外 UltraEdit 中文版在使用上可能會發生問題 如：巨集命令"Key DOWN ARROW"
要改成 "Key 向下"
若不知道怎麼改,可以叫出 UltraEdit 巨集點選命令查看,先尋找 Key 命令,在
下方非數值參數視窗尋找符合的命令

常用 UltraEdit 巨集指令介紹
----------------------------------------------------
當新建一個巨集時，下列4行巨集命令將自動產生到巨集中
所以下面的範例複製到這4行命令下面即可
InsertMode
ColumnModeOff
HexOff
UnixReOff

指令：
ClearClipboard 清除 UltraEdit 內部作用中剪貼簿內容
Copy 複製選定的文字到剪貼簿中
Cut 剪下放置到剪貼簿
Delete 刪除或選定的文字
DeleteLine 刪除目前行
DeleteToEndofLine 刪除從目前游標位置到行尾的內容
DeleteToStartofLine 刪除從行首到目前游標位置的內容
Else 如果 If 命令失敗則執行Else之後命令
EndIf 結束 If... 敘述
EndLoop 結束Loop… 迴圈
EndSelect 停止選擇文字
ExitLoop 跳出Loop… 迴圈
ExitMacro 結束巨集(這指令沒放在巨集結尾一樣會結束)
Find 搜尋""的字元 如:"ABC"
IfEof 如果在檔最末端則執行這些命令
IfFound 如果 Find 找到指定字元時則執行 IfFound 到 Endif 之間的命令
IfNotFound 如果 Find 未找到指定字元時則執行 IfNotFound 到 Endif 之間的命令
InsertLine 在游標目前位置的下面插入空白行
Loop 執行 Loop 到 EndLoop 之間的命令，Loop # 迴圈執行 # 次，
MatchBrace 尋找符合的成對符號，並選中它們之間的文字
NewFile 開啟一個新的空白檔
NextDocument 切換到下一個檔標籤檔
NextWindow 切換到下一個視窗
Paste 貼上
StartSelect 標記選取模式 EndSelect 可停止
SelectAll 選中檔中的所有文字
SelectLine 選中作用行中的所有文字
SpacesToTabs 轉換檔內的 (行首) 空格為定位字元
TabsToSpaces 轉換檔案中的所有TAB為空格
Top 跳到檔起始位置
ToUpper 轉換選定的文字為大寫字母
TrimTrailingSpaces 刪除目前檔案中每行後面的多餘空格

Key 如同您按下鍵盤按鍵(UltraEdit 中文版 可能要改成中文才能執行)
Key BACKSPACE
Key DEL
Key DOWN ARROW
Key END
Key HOME
Key LEFT ARROW
Key PGDN
Key PGUP
Key RIGHT ARROW
Key UP ARROW
Key Ctrl+END
Key Ctrl+HOME
Key Ctrl+LEFT ARROW
Key Ctrl+RIGHT ARROW

範例：
功能：字典用刪除多餘內容空格 = 號以下複製到 UltraEdit 巨集
=================================
TabsToSpaces

Top
Loop
Find "\t"
IfFound
DeleteToEndofLine
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find ":"
IfFound
" "
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find "："
IfFound
" "
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find "..."
IfFound
" "
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find "…"
IfFound
" "
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find "(&"
IfFound
StartSelect
Find Select ")"
IfNotFound
ExitLoop
EndIf
EndSelect
" "
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find "&"
IfFound
Delete
Else
ExitLoop
EndIf
EndLoop

TrimTrailingSpaces
Top
ExitMacro

功能：留下功能鍵內容+括號 = 號以下複製到 UltraEdit 巨集
=================================
TabsToSpaces
Top
Loop
Find " "
IfFound
Delete
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Key HOME
" "
Key END
IfEof
ExitLoop
EndIf
Key DOWN ARROW
EndLoop

Top
Loop
Find "&"
IfFound
DeleteToStartofLine
"("
Key RIGHT ARROW
Key RIGHT ARROW
")"
DeleteToEndofLine
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find " "
IfFound
Key HOME
Key HOME
DeleteToEndofLine
Else
ExitLoop
EndIf
EndLoop
SelectAll
ToUpper
Top
ExitMacro

功能：留下冒號3點 = 號以下複製到 UltraEdit 巨集
=================================
TabsToSpaces
Top
Loop
Find " "
IfFound
Delete
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Key HOME
" "
Key END
IfEof
ExitLoop
EndIf
Key DOWN ARROW
EndLoop

Top
Loop
Find ":"
IfFound
DeleteToStartofLine
Key END
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find "："
IfFound
Key HOME
Key HOME
DeleteToEndofLine
":"
Key END
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find "..."
IfFound
DeleteToStartofLine
Key RIGHT ARROW
Key RIGHT ARROW
Key RIGHT ARROW
DeleteToEndofLine
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find " "
IfFound
Key HOME
Key HOME
DeleteToEndofLine
Else
ExitLoop
EndIf
EndLoop
Top
ExitMacro

功能：留下\t內容 = 號以下複製到 UltraEdit 巨集
=================================
TabsToSpaces
Top
Loop
Find " "
IfFound
Delete
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Key HOME
" "
Key END
IfEof
ExitLoop
EndIf
Key DOWN ARROW
EndLoop

Top
Loop
Find "\t"
IfFound
DeleteToStartofLine
Key END
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Find " "
IfFound
Key HOME
Key HOME
DeleteToEndofLine
Else
ExitLoop
EndIf
EndLoop
Top
ExitMacro

功能：留下大中小括弧內容 = 號以下複製到 UltraEdit 巨集
=================================
TabsToSpaces
Top
Loop
Find " "
IfFound
Delete
Else
ExitLoop
EndIf
EndLoop

Top
Loop
Key HOME
" "
Key END
IfEof
ExitLoop
EndIf
Key DOWN ARROW
EndLoop

Top
Loop
ClearClipboard
MatchBrace
Cut
Key HOME
Key HOME
DeleteToEndofLine
Paste
Key END
IfEof
ExitLoop
EndIf
EndLoop

Top
Loop
Find " "
IfFound
Key HOME
Key HOME
DeleteToEndofLine
Else
ExitLoop
EndIf
EndLoop
Top
ExitMacro